第3回^[1]からパスの文法を調べてきました。パスの重要な構成要素にステップがあり、ステップ（省略）は軸、ノードテスト、述部（オプションなので必須ではない）から構成されることを調べました。

ステップの最後の構成部品はオプションの述部です。第6回^[2]で見ましたが、述部は式を[]で囲った形式です。

式とはどんなものでしょうか？　まず、XPathの式の生成規則^[3]をトップから辿ってみます。

スタートは定義の[14]ですが、式Exprとは、OrExprです。[21]orExprはAndExprを’or’でつなげたものです。そして、[22]AndExprとは、EqualityExprを’and’でつなげたものです。[23]EqualityExprは、RelationalExprを’=’でつなげたものまたは’!=’でつなげたもの。[24]RelationalExprは、AdditiveExprを'<‘ ‘>”<=’ ‘>=’でつなげたもののようです。つまり、このあたりまでは、式はAdditiveExpr（加算式）の論理演算ということになります。

[14] Expr ::= OrExpr
[21] OrExpr ::= AndExpr | OrExpr ‘or’ AndExpr
[22] AndExpr ::= EqualityExpr | AndExpr ‘and’ EqualityExpr
[23] EqualityExpr ::= RelationalExpr
| EqualityExpr ‘=’ RelationalExpr
| EqualityExpr ‘!=’ RelationalExpr
[24] RelationalExpr ::= AdditiveExpr
| RelationalExpr ‘<‘ AdditiveExpr | RelationalExpr ‘>’ AdditiveExpr
| RelationalExpr ‘<=’ AdditiveExpr | RelationalExpr ‘>=’ AdditiveExpr

ということで、さらにAdditiveExprとは何かを見てみます。[25]ではAdditiveExprは、MultiplicativeExprを’+’または’-‘でつなげたものです。

[25] AdditiveExpr ::= MultiplicativeExpr
| AdditiveExpr ‘+’ MultiplicativeExpr
| AdditiveExpr ‘-‘ MultiplicativeExpr

[26]ではMultiplicativeExprとは、UnaryExpr（単項式）、またはMultiplicativeExprにUnaryExprを掛けた（’*’）、またはMultiplicativeExprをUnaryExprで割り算（’div’）、剰余算（’mod’）したものです。
[26] MultiplicativeExpr ::= UnaryExpr
| MultiplicativeExpr MultiplyOperator UnaryExpr
| MultiplicativeExpr ‘div’ UnaryExpr
| MultiplicativeExpr ‘mod’ UnaryExpr
[34] MultiplyOperator ::= ‘*’

UnaryExprは、UnionExprまたはその前にマイナス記号（’-‘）をつけたもの。

[27] UnaryExpr ::= UnionExpr | ‘-‘ UnaryExpr

UnionExprは、ひとつのPathExpr（パス式）、またはそれを’|’で結合したものです。

[18] UnionExpr ::= PathExpr| UnionExpr ‘|’ PathExpr

PathExpr式は、LocationPath（ロケーションパス）、またはFilterExprまたは、FilterExprと相対ロケーションパスを’/’、’//’ で結合したものです。

[19] PathExpr ::= LocationPath
| FilterExpr
| FilterExpr ‘/’ RelativeLocationPath
| FilterExpr ‘//’ RelativeLocationPath

ロケーションパスについては第３回^[2]ですでに学びましたが、XMLツリーのノードを選択するものです。ノードの選択結果はノードの集まり（ノード集合）ですが、これに対して、掛け算（’*’）、割り算（’div’）、剰余算（’mod’）、足し算（’+’）、引き算（’-‘）、比較などの演算をするのは少し不思議な気もします。これは後ほど調べてみることにします（^[5]）。

FilterExprの方は、PrimaryExprまたはPrimaryExprに述部（Predicate）を付けたものとなります。ここに出てくる述部はFilterExpr Predicateのように使われますが、ステップの中で出てくる述部の使われ方はAxisSpecifier NodeTest Predicate*です。この2種類の述部の使われ方の違いはなんでしょうか？　これも後ほど調べてみましょう（^[4]）。

PrimaryExprは、VariableReference（変数参照）、式を()で囲ったもの、リテラル、数値、FunctionCall（関数呼び出し）のどれかです。ですので、式には数置の四則演算も表現したものも含まれます（よく知っている初歩的な数式も含まれるということで一安心です）。

[20] FilterExpr ::= PrimaryExpr
| FilterExpr Predicate
[15] PrimaryExpr ::= VariableReference
| ‘(‘ Expr ‘)’
| Literal
| Number
| FunctionCall

最も単純なケースでは、一つの数値（Number）だけでも式となります。例えば、次のように下から辿ってみます。
(1) PrimaryExprがNumber:100
(2) FilterExprがPrimaryExpr:100
(3) PathExprがFilterExpr:100
(4) UnionExprがPathExpr:100
(5) UnaryExprがUnionExpr :100
(6) MultiplicativeExprがUnaryExpr:100
(7) AdditiveExprがMultiplicativeExpr:100
(8) RelationalExprがAdditiveExpr :100
(9) EqualityExprがRelationalExpr :100
(10) AndExprがEqualityExpr:100
(11) OrExprがAndExpr:100
(12) ExprがOrExpr:100

ということで、述部に[100]と書くことができます。

まとめますと、述部（[]内）には式を書きますが、式としてはロケーションパスを書くこともできますし、また、数値、変数、関数呼び出し、数式を書くこともできる、ということになります。

途中で、いろいろわからない言葉が出てきていますので、次回以降、もう少し詳しく調べてみます。

[1] XSLTを学ぶ　（3） パスとは
[2] XSLTを学ぶ　（6） ステップの文法を追求するの[8]、[9]式
[3] 3 Expressions
[4] 次回（第10回）のpreceding::foo[1] と(preceding::foo)[1]の比較 の項を参照してください。
[5] ノード集合の論理演算、比較演算については第11回を参照してください。

【広告】★AH Formatter XML関連出版物の紹介

次回:
XSLTを学ぶ　（10）式によるノード集合の作成、ノード集合の和集合、フィルター式

前回:
XSLTを学ぶ（8）ステップの文法を追求する-NodeTest

初回:
XSLTを学ぶ（1）XMLのツリーモデルとXPath/XSLTのツリーモデルではルートの意味が違う

Tweet